FINISH !

close all previous modules

/CLEAR !clear all previous models
/TITLE, Horizontal plate
/PREP7 !start PRE-PROCESSOR MODULE
!geometric parameters (mm)
length=900 ! mm
width=2100 ! mm
thickness=10 ! mm
ET,1,SHELL181 !element type #1: SHELL181 (6 DoF)
KEYOPT,1,3,2 !element #1: keyoption 3=2 (full integration incompatibl
e modes)
SECTYPE,1,SHELL !section #1: shell
SECDATA,thickness !thickness
MP,EX,1,15000 !Young's modulus for material #1 in N/mm2
MP,PRXY,1,0.3 !Poisson ratio for material #1
MP,DENS,1,40e-9 !material property #1: Density in kg/mm^3
!define keypoints and area
K,1,0,0 !keypoint, #, x, y
K,2,width,0
K,3,width,length
K,4,0,length
A,1,2,3,4 !area through keypoints
!element definition
AESIZE,ALL,100 !specifies the element size to be meshed onto areas
AMESH,ALL !mesh all areas
FINISH
/SOLU !start SOLUTION MODULE
!apply boundary conditions
DK,1,UZ,0,,,UX,UY !define a DOF constraint at a keypoint (ux=uy=uz=0)
DK,2,UZ,0,,,UY !define a DOF constraint at a keypoint (uy=uz=0)
DK,3,UZ,0
DK,4,UZ,0
!apply loads
ACEL,,,9.81 !acceleration in m/s^2, kg*m/s^2 = N
SOLVE !solve the resulting system of equations,
FINISH
/POST1 !start POST-PROCESSOR MODULE
PLNSOL,U,SUM,0,1 !contour plot of deflection