UNIVERSIDAD DE EL SALVADOR

FACULTAD DE INGENIERÍA Y ARQUITECTURA

ESCUELA DE INGENIERÍA ELÉCTRICA
ANÁLISIS ELÉCTRICO I
CICLO I - 2018

Catedrático: Ing. Gerardo Marvin Jorge Hernández.

Instructores: Br. Karen Amanda Agreda Rivas.
Br. Aura Lucia Mendoza Merlos.

Guía de Simulación IV: Valores Medios y RMS.

Ejemplo 1. Para el siguiente circuito calcular la potencia disipada por R1 (potencia promedio)
y el valor RMS de la corriente 𝑖(𝑡).

Código en SPICE OPUS:

* Ejemplo 1.
* Guía de Simulación IV.
* AEL115 Ciclo I-2017.

* Fuentes de tensión senoidales.

Vs 1 0 DC 0V AC {115*sqrt(2)}V 0deg
* Fuentes de tensión independientes de DC.
Vx 1 2 DC 0V
* Resistencias.
R1 2 3 1kOhm
R2 3 0 1kOhm
.control
set units=degrees
* Análisis en Frecuencia.
ac dec 1 60Hz 60Hz
* Es entre dos porque estamos trabajando con valores máximos.
let pr1_prom=Mag(V(2,3)*i(Vx)/2)
* Es entre raíz de dos porque estamos trabajando con valores máximos.
let irms=Mag(i(Vx)/sqrt(2))
echo
echo Potencia Promedio Disipada por R1 [W]:
echo
print Pr1_prom
echo
echo Corriente RMS [A]:
echo
print Irms
echo
destroy all
.endc
.end

Ejemplo 2. Graficar la corriente 𝑖(𝑡) conjuntamente a 𝑣(𝑡), determinar el valor RMS de la

corriente, el ángulo de fase de la corriente y la impedancia de entrada vista desde la fuente
(tanto en forma compleja como en magnitud y ángulo de impedancia). La frecuencia de
operación del sistema es f = 60 Hz. C = 2.65258238486 mF (XC = 1 Ω), L = 13.2629119243
mH (XL = 5 Ω).

Código en SPICE OPUS:

* Ejemplo 2.
* Guía de Simulación IV.
* AEL115 Ciclo I-2017.

* Fuentes de tensión senoidales.

Vs 1 0 DC 0V AC 60V 0deg SIN ( 0V {60*sqrt(2)}V 60Hz 0s 0 0deg )
* Fuentes de tensión independientes de DC.
Vx 1 2 DC 0V
* Resistencias.
R1 2 3 2Ohm
R2 4 5 1Ohm
* Capacitores.
* C 3 4 {1/(2*pi*60*1)}
C 3 4 2.65258238486mF
* Inductores.
* L 5 0 {5/{2*pi*60}}
L 5 0 13.2629119243mH
.control
set units=degrees
* Análisis Transitorio.
tran 0.1us 45ms 0ms 1us
plot i(Vx) V(1) vs (time*1k) xlabel 'Tiempo [ms]' ylabel 'Corriente [A]
+ y Tensión [V]'
+title 'Gráficos de corriente [roja] y tensión [verde]'
destroy all
* Análisis en Frecuencia.
ac dec 1 60Hz 60Hz
let zent=V(1)/i(Vx)
let zent_mag=Mag(zent)
let theta_zent=ph(zent)
let irms=Mag(i(Vx))
let theta_i=ph(i(Vx))
echo
echo Corriente RMS [A]:
echo
print Irms
echo
echo Angulo de la corriente [Grados]:
echo
print theta_i
echo
echo Impedancia de entrada [Ohm]:
echo
print Zent
echo
echo Magnitud de la impedancia de entrada [Ohm]:
echo
print Zent_Mag
echo
echo Angulo de la impedancia de entrada [Grados]:
echo
print theta_zent
echo
destroy all
.endc
.end