Página 1 de 15

Imprimir esta página

Operadores e funções de fórmula de A – H | Salesforce.com

Operadores e funções de fórmula de A – H

Use os operadores e funções a seguir na criação de fórmulas. Clique no nome do operador ou função abaixo
para exibir mais detalhes. Todas as funções estão disponíveis em toda parte, de forma que é possível incluir
uma fórmula como campos de fórmula, regras de validação, processos de aprovação e regras de fluxo de
trabalho, a não ser que haja alguma especificação diferente.

Nota
Espaços alheios nos exemplos abaixo são ignorados.

+ (Somar)

Descrição: Calcula a soma de dois valores.

Use: value1 + value2 e substitua cada value por campos de mesclagem,
expressões ou outros valores numéricos.
Exemplo de campo de Amount + Maint_Amount__c + Services_Amount__c
fórmula:
Esta fórmula calcula a soma do Valor da oportunidade, do valor de manutenção
e das taxas de serviço. Observe que Valor de manutenção (Maint amount)
e Taxas de serviço (Service Fees) são campos de moeda personalizados.
Exemplo de relatório: EMAIL_OPT_OUT:SUM + DO_NOT_CALL:SUM calcula todos os campos de
Recusa de email e Não chamar nos leads do seu relatório. Essa fórmula é
um tipo de dados numéricos que retorna um número inteiro positivo.
Exemplo de regra de Você pode ter um objeto personalizado que permita aos usuários rastrear o
validação: número total de horas trabalhadas em uma semana. Use o exemplo a seguir para
garantir que os usuários não guardem um registro de folha de ponto com mais de
40 horas em uma semana de trabalho.
Monday_Hours__c +
Tuesday_Hours__c +
Wednesday_Hours__c +
Thursday_Hours__c +
Friday_Hours__c > 40

Use uma fórmula como esta em uma regra de validação para exibir a seguinte
mensagem de erro quando o número total de horas inseridas para cada dia de
trabalho for superior a 40: “O total de horas não pode exceder 40”. O exemplo
requer cinco campos personalizados no objeto personalizado, um para cada dia
de trabalho.

- (Subtrair)

Descrição: Calcula a diferença entre dois valores.

Use: value1 - value2 e substitua cada value por campos de mesclagem,
expressões ou outros valores numéricos.
Exemplo: Amount - Discount_Amount__c
Esta fórmula calcula a diferença entre o Valor do produto e seu Valor do
desconto (Discount Amount). Observe que Valor do desconto é um
campo de moeda personalizado.

http://help.salesforce.com/apex/HTPrint?id=customize_functions_a_h.htm&language... 20/01/2014
 Página 2 de 15

Exemplo de relatório: AMOUNT:SUM - Opportunity.Discount_Amount__c:SUM calcula a

diferença entre todos os campos de Valor e Valor com desconto
(Discounted Amount) personalizados nos produtos do seu relatório. Essa fórmula
usa um tipo de dados de moeda que retorna um símbolo de moeda e casas
decimais.

* (Multiplicar)

Descrição: Multiplica os seus valores.

Use: value1 * value2 e substitua cada value por campos de mesclagem,
expressões ou outros valores numéricos.
Exemplo: Consulting_Days__c * 1200
Esta fórmula calcula o número de dias de consultoria vezes 1200, considerando
que esse campo de fórmula é um tipo de dados de moeda e a consultoria cobra
uma taxa de US$ 1.200,00 por dia. Observe que Dias de consultoria
(Consulting Days) é um campo personalizado.
Exemplo de relatório: RowCount * AGE:AVG calcula o número de registros vezes a duração média
do seu relatório. Essa fórmula é um tipo de dados numérico que retorna um
número inteiro ou um decimal, positivo ou negativo.

/ (Dividir)

Descrição: Divide seus valores.

Use: value1 / value2 e substitua cada value por campos de mesclagem,
expressões ou outros valores numéricos.
Exemplo: AnnualRevenue/ NumberOfEmployees

Esta fórmula calcula o valor da receita por funcionário usando um campo de

moeda.
IF(NumberOfOpportunities > 0,
NumberOfWonOpportunities / NumberOfOpportunities,
null)

Esta fórmula calcula a taxa de ganho de oportunidades em uma campanha.

Exemplo de relatório: Porcentagem de oportunidades ganhas

WON:SUM / RowCount calcula a porcentagem de oportunidades Ganhas

usando um número de registros que representa o total das oportunidades do seu
relatório. Essa fórmula é um tipo de dados numérico que retorna um número
inteiro positivo ou negativo.

Diferença percentual entre os preços de custo e de venda

(TOTAL_PRICE:SUM - QUANTITY:SUM *
Product2.Cost__c:SUM) / (QUANTITY:SUM *
Product2.Cost__c:SUM) calcula a diferença média em termos percentuais
entre o custo de um produto e seu preço de venda por produto. Observe que
Product2.Cost__c:SUM é um campo de moeda personalizado chamado
Custo em produtos, que inclui o custo de cada produto. Essa fórmula é um tipo
de dados percentuais que retorna um número inteiro positivo ou negativo. Para
obter os melhores resultados, use essa fórmula em um relatório resumido de
Oportunidades com produtos, que é resumido por Nome do produto e inclui
totais resumidos de Quantidade, Preço total e Custo.

^ (Exponenciação)

Descrição: Eleva um número a uma potência especificada.

http://help.salesforce.com/apex/HTPrint?id=customize_functions_a_h.htm&language... 20/01/2014
 Página 3 de 15

Use: number^integer e substitua number por um campo de mesclagem, expressão ou

outro valor numérico e integer por um campo de mesclagem que contenha um
número inteiro, uma expressão ou qualquer inteiro.
Exemplo: NúmerodeFuncionários^4 calcula o número de funcionários elevado à
quarta potência.
Exemplo de relatório: ACTIVE:SUM ^ 2 calcula o número de usuários ativos do Salesforce elevado à
segunda potência para administração. Essa fórmula é um tipo de dados de
número que retorna um número inteiro positivo.
Dicas: Evite substituir o número inteiro por um número negativo.

() (Parênteses de abertura e de fechamento)

Descrição: Especifica que as expressões entre parênteses são avaliadas em primeiro lugar.
Todas as outras expressões são avaliadas com a precedência do operador
padrão.
Use: (expression1) expression2... e substitua cada expression por campos de
mesclagem, expressões ou outros valores numéricos.
Exemplo: (Unit_Value__c - Old_Value__c) / New_Value__c calcula a
diferença entre o valor antigo e o novo, dividida pelo valor novo.
Exemplo de relatório: (DURATIONHOURS:SUM * RowCount) / 24 calcula a duração de todos os
compromissos vezes o número de registros por 24 horas. Essa fórmula é um tipo
de dados percentuais que retorna um número inteiro ou um decimal, positivo ou
negativo, representando a porcentagem do dia dedicada a compromissos.

= e == (igual)

Importante
Não use essa função para uma comparação nula, como MyDateTime__c == null. Ao invés
disso, use ISBLANK.

Descrição: Avalia se dois valores são equivalentes.

Use: expression1=expression2 ou expression1 == expression2, e substitua cada
expression por campos de mesclagem, expressões ou outros valores numéricos.
Exemplo: Data de vencimento

Data de vencimento = CreatedDate + 5 atribui uma data de

vencimento cinco dias após a data de criação.

Valor da comissão
IF(Probability =1, ROUND(Amount*0.02, 2), 0)

Esta fórmula calcula o valor da comissão de 2% de uma oportunidade cuja

probabilidade é 100%. Todas as demais oportunidades terão um valor de
comissão de 0.

Possíveis resultados:

◾ Uma oportunidade com Probabilidade de 90% terá uma comissão de 0.

◾ Uma oportunidade com Probabilidade de 100% e um Valor de US$
100.000,00 terá uma comissão de US$ 2.000,00.

<> e != (não igual)

Importante
Não use essa função para uma comparação nula, como MyDateTime__c != null. Ao invés
disso, use ISBLANK.

http://help.salesforce.com/apex/HTPrint?id=customize_functions_a_h.htm&language... 20/01/2014
 Página 4 de 15

Descrição: Avalia se dois valores não são equivalentes.

Use: expression1 <> expression2 ou expression1 != expression2, e substitua cada
expression por campos de mesclagem, expressões ou outros valores
numéricos.
Exemplo: IF(Maint_Amount__c + Services_Amount__c<> Amount,
"DISCOUNTED", "FULL PRICE")

Esta fórmula exibirá “COM DESCONTO” em um produto se o respectivo valor de

manutenção e as taxas de serviços não forem iguais ao valor do produto. Caso
contrário, “PREÇO INTEGRAL” será exibido. Observe que esse exemplo usa dois
campos de moeda personalizados para Valor de manutenção (Maint
Amount) e Taxa de serviços (Services Amount).

< (Menor que)

Descrição: Avalia se um valor é menor que aquele após o símbolo.

Use: value1 < value2 e substitua cada value por campos de mesclagem, expressões
ou outros valores numéricos.
Exemplo: IF(AnnualRevenue < 1000000, 1, 2) atribui o valor “1” a receitas
menores que um milhão e o valor “2” a receitas maiores que um milhão.

> (Maior que)

Descrição: Avalia se um valor é maior que aquele após o símbolo.

Use: value1 > value2 e substitua cada value por campos de mesclagem, expressões ou
outros valores numéricos.
Exemplo: IF (commission__c > 1000000, "Patrimônio líquido alto",
"Geral") atribui o valor de “Patrimônio líquido alto” a comissões acima de um
milhão. Observe que esse é um campo de fórmula de texto que utiliza um campo
personalizado de comissão.

<= (Menor que ou igual a)

Descrição: Avalia se um valor é menor que ou igual àquele após o símbolo.

Use: value1 <= value2 e substitua cada value por campos de mesclagem, expressões
ou outros valores numéricos.
Exemplo: IF(AnnualRevenue < 1000000, 1, 2) atribui o valor “1” a receitas
menores ou iguais a um milhão e o valor “2” a receitas maiores que um milhão.

>= (Maior que ou igual a)

Descrição: Avalia se um valor é maior que ou igual àquele após o símbolo.

Use: value1 >= value2 e substitua cada value por campos de mesclagem, expressões
ou outros valores numéricos.
Exemplo: IF (Commission__c >= 1000000, "SIM", "NÃO") atribui o valor “SIM” a
oportunidades com uma comissão superior ou igual a um milhão. Observe que
esse é um campo de fórmula de texto que utiliza um campo de moeda
personalizado denominado Comissão (Commission).

&& (E)

Descrição: Avalia se dois valores ou expressões são verdadeiros. Use esse operador como
alternativa à função lógica E.

http://help.salesforce.com/apex/HTPrint?id=customize_functions_a_h.htm&language... 20/01/2014
 Página 5 de 15

Use: (logical1) && (logical2) e substitua logical1 e logical2 pelos valores ou

expressões que você deseja avaliar.
Exemplo: IF((Price<100 && Quantity<5),"Small", null)

Essa fórmula exibe “Pequeno” se o preço for inferior a 100 e a quantidade for
inferior a cinco. Caso contrário, esse campo ficará em branco.

|| (OU)

Descrição: Avalia se pelo menos um dos vários valores ou expressões é verdadeiro. Use
esse operador como alternativa à função lógica OU.
Use: (logical1) || (logical2) e substitua qualquer número de referências lógicas
pelas expressões que deseja avaliar.
Exemplo: IF((ISPICKVAL(Priority , "Alta")) || (ISPICKVAL
(Status , "Novo")), ROUND(NOW()-CreatedDate, 0), null)

Esta fórmula retorna o número de dias durante os quais um caso esteve aberto se
o Status for novo ou a Prioridade for alta. Se o caso tiver sido aberto hoje,
o campo exibirá zero.
Exemplo de regra de 
(Discount_Rate__c < 0) || (Discount_Rate__c > 0.40) 
validação:
Esta fórmula de regra de validação exibirá a seguinte mensagem de erro quando o
campo personalizado Taxa de desconto (Discount Rate) não estiver entre 0
e 40%: "Taxa de desconto não pode exceder 40%" (Discount Rate cannot exceed
40%).

& (Concatenado)

Descrição: Conecta duas ou mais strings.

Use: string1&string2 e substitua cada string por campos de mesclagem, expressões ou
outros valores.
Exemplo: "Despesa-" & Trip_Name__c & "-" & ExpenseNum__c
Esta fórmula exibe o texto “Despesa- ” seguido do nome da viagem e do número
da despesa. Esse é um campo de fórmula de texto que usa um campo
personalizado de número da despesa.

ABS

Descrição: Calcula o valor absoluto de um número. O valor absoluto de um número é o

número sem o sinal de positivo ou negativo.
Use: ABS(number) e substitua number por um campo de mesclagem, expressão ou
outro valor numérico com o sinal a ser removido.
Exemplo: ABS(ExpectedRevenue) calcula o valor positivo do valor da Receita
esperada, seja ele positivo ou negativo.

Descrição: Retornará a resposta TRUE se todos os valores forem verdadeiros ou FALSE se

um ou mais valores forem falsos. Use essa função como alternativa ao operador
&& (E).
Use: AND (lógico1,lógico2,...) e substitua lógico1,lógico2,... pelos valores
que deseja avaliar.
Exemplo de campo de IF(AND(Price<1,Quantity<1),"Pequeno", null)
fórmula:

http://help.salesforce.com/apex/HTPrint?id=customize_functions_a_h.htm&language... 20/01/2014
 Página 6 de 15

Esta fórmula exibirá “Pequeno” se o preço e a quantidade forem menores que um.
Esse campo ficará em branco se o preço ou a quantidade do patrimônio for maior
que 1.

BEGINS

Descrição: Determina se o texto começa com caracteres específicos e retorna TRUE se isso
acontecer. Caso contrário, retornará FALSE.
Use: BEGINS(texto, comparar_texto) e substitua texto, comparar_texto pelos
caracteres ou campos a serem comparados.
Exemplo: IF(BEGINS (Product_type__c , "ICU"), "Médico",
"Técnico")

Este exemplo retornará o texto “Médico” se o texto de um campo de texto

personalizado de Tipo de produto (Product Type) começar com “ICU”. Em
todos os demais produtos, “Técnico” será exibido.
Dicas:
◾ Esta função diferencia maiúsculas de minúsculas, portanto assegure que o
valor comparar_texto use as letras corretas.
◾ Quando essa função é usada em uma regra de validação ou de fluxo de
trabalho, os campos em branco são considerados válidos. Por exemplo, se
você tiver uma regra de validação que verifica se o número de série de um
patrimônio começa com “3”, todos os patrimônios com um número de série
em branco serão considerados válidos.

BLANKVALUE

Descrição: Determina se uma expressão tem um valor e, caso não tenha, se retorna uma
expressão substituta. Se a expressão tiver um valor, retornará o valor da
expressão.
Use: BLANKVALUE(expression, substitute_expression) e substitua
expression pela expressão a ser avaliada; substitua substitute_expression pelo
valor a substituir qualquer valor em branco.
Exemplo: Exemplo 1

BLANKVALUE(Departamento, “Não atribuído”)

Essa fórmula retorna o valor do campo Departamento se o campo

Departamento contiver um valor. Se o campo Departamento estiver vazio,
essa fórmula retornará a palavra Não atribuído.

Exemplo 2

(BLANKVALUE(Payment_Due_Date__c, StartDate +5)

Esta fórmula retorna a data cinco dias após a data de início do contrato sempre
que o campo Data de vencimento do pagamento (Payment Due Date)
é deixado em branco. Data de vencimento do pagamento é um campo
de data personalizado.
Dicas:
◾ Use BLANKVALUE em vez de NULLVALUE nas novas fórmulas.
BLANKVALUE tem a mesma funcionalidade que NULLVALUE, mas também
suporta campos de texto. O Salesforce continuará suportando NULLVALUE,
de modo que você não precisa alterar as fórmulas existentes.
◾ Um campo não estará vazio se contiver um caractere, espaço em branco ou
zero. Por exemplo, um campo que contiver um espaço inserido com a barra
de espaço não está vazio.

http://help.salesforce.com/apex/HTPrint?id=customize_functions_a_h.htm&language... 20/01/2014
 Página 7 de 15

◾ Use a função BLANKVALUE para retornar uma string específica se o campo

não tiver um valor; use a função ISBLANK se você quiser apenas verificar se
o campo tem um valor.
◾ Se você usar essa função com um campo numérico, a função retornará
somente a string especificada se o campo não tiver um valor e não estiver
configurado para considerar campos em branco como zeros.

BR

Descrição: Insere uma quebra de linha em uma string de texto.

Use: BR()
Exemplo: CASE(ShippingCountry,
"USA",
ShippingStreet & BR() &
ShippingCity & ",
" & ShippingState & " " &
ShippingPostalCode & BR()
& ShippingCountry,
"France",
ShippingStreet & BR() &
ShippingPostalCode & " " &
ShippingCity & BR() &
ShippingCountry, "etc")

Esta fórmula exibe um endereço de correspondência formatado para um contato

em formato padrão, incluindo espaços e quebras de linha quando apropriado, de
acordo com o país.
Dicas:
◾ Não remova os parênteses após o nome da função.
◾ Deixe os parênteses vazios. Eles não precisam conter um valor.
◾ Lembre-se de colocar BR() entre operadores de concatenação: &.
◾ Evite usar essa função em modelos de mala direta.
◾ Essa função não está disponível em botões e links personalizados, s-
controls ou relatórios.

CASE

Descrição: Compara determinada expressão a uma série de valores. Se a expressão for igual
a um valor, retornará o resultado correspondente. Se ela não for igual a nenhum
valor, retornará outro_resultado.
Use: CASE(expression,value1, result1, value2, result2,...,
else_result) e substitua expression pelo campo ou valor a ser comparado com
cada valor específico. Substitua os valores e resultados pelos valores que deverão
ser equivalentes para que os resultados indicados sejam retornados. Substitua
else_result pelo valor a ser retornado quando a expressão não for equivalente a
nenhum outro valor.
Exemplo de campo de Dias em aberto para casos
fórmula:
Use esse exemplo de campo de fórmula personalizado denominado Dias em
aberto para exibir textos diferentes dependendo do número de dias em que um
caso ficou em aberto:
CASE(Days_Open__c, 3,
"Reassign", 2, "Assign Task", "Maintain")

O texto a seguir é exibido:

http://help.salesforce.com/apex/HTPrint?id=customize_functions_a_h.htm&language... 20/01/2014
 Página 8 de 15

◾ “Reatribuir” para qualquer caso aberto há três dias.

◾ “Atribuir tarefa” para qualquer caso aberto há dois dias.
◾ “Manter” para todos os demais casos.

Mês da última atividade

Este campo de fórmula exibe o mês da última atividade ou “Nenhum” se não

houver atividades.
CASE(MONTH(LastActivityDate),
1, "January",
2, "February",
3, "March",
4, "April",
5, "May",
6, "June",
7, "July",
8, "August",
9, "September",
10, "October",
11, "November",
12, "December",
"None")
Exemplo de valor Taxa de desconto
padrão:
Use a seguinte fórmula de valor padrão para inserir outra taxa de desconto em
uma oportunidade, com base no departamento da pessoa que está criando a
oportunidade:

CASE(User.Department, "IT", 0.25, "Field", 0.15, 0) 

Nesse exemplo, a fórmula insere uma taxa de desconto de 25% em qualquer

oportunidade criada por um usuário no departamento de “TI” ou 15% em qualquer
oportunidade criada por alguém no departamento de “Campo”. Um zero será
aplicado ser o criador não pertencer a um desses departamentos. Este é um
campo de porcentagem personalizado em oportunidades que usa o campo de
usuário padrão Departamento.

Idioma do produto

Talvez você queira associar um produto a seu idioma para que seus usuários
saibam o tipo de documentação ou adaptador a ser incluído. Use a fórmula de
valor padrão a seguir para definir automaticamente o idioma de um produto com
base na país do usuário que está criando o produto. Nesse exemplo, o valor
padrão será “japonês” se o país do usuário for “Japão” e “inglês” se o país do
usuário for “EUA” Se nenhum desses valores for aplicável, o valor padrão
“desconhecido” será inserido no campo Idioma do produto.
CASE($User.Country , "Japan", "Japanese", "US",
"English","unknown")
Dicas:
◾ Verifique se as expressões valor1, valor2... são do mesmo tipo de dados.
◾ Verifique se as expressões resultado1, resultado2... são do mesmo tipo de
dados.
◾ As funções CASE não podem conter funções que retornem verdadeiro ou
falso. Verifique se as expressões verdadeiras ou falsas retornam números
como:
CASE(1, IF(ISPICKVAL (Term__c, "12"), 1, 0),
12 * Monthly_Commit__c, 
IF(ISPICKVAL(Term__c, "24"), 1, 0), 
24 * Monthly_Commit__c, 0)

http://help.salesforce.com/apex/HTPrint?id=customize_functions_a_h.htm&language... 20/01/2014
 Página 9 de 15

Nessa fórmula, Prazo é um campo da lista de opções que será multiplicado

pela Confirmação mensal sempre que contiver o valor 1 para verdadeiro.
◾ O valor de outro_resultado é obrigatório.
◾ As funções CASE retornam um erro sempre que qualquer expressão resultar
em erro, independentemente do erro retornado. Por exemplo: CASE
(Field__c,"Partner", "P", "Customer", "C", LEFT
(Field__c, -5)) retornará um erro mesmo se o valor do campo for
“Parceiro” ou “Cliente”, pois a última instrução não é lógica.
◾ Se o campo da função CASE for deixado em branco, será retornado o valor
outro_resultado. Por exemplo, esta fórmula: CASE(Days_Open__c, 3,
"Reatribuir", 2, "Atribuir tarefa", "Manter") exibirá
“Manter” se o campo Dias em aberto estiver em branco ou contiver 0
ou qualquer valor diferente de 2 ou 3.
◾ Use funções do tipo CASE para determinar se o valor de uma lista de
opções é igual a um determinado valor. Por exemplo, a fórmula CASE
(Term__c, "12", 12 * Monthly_Commit__c, "24", 24 *
Monthly_Commit__c, 0) multiplicará o valor da Confirmação
mensal por 12 sempre que o Prazo for 12 ou multiplicará o valor da
Confirmação mensal por 24 sempre que o Prazo for 24. Do contrário,
o resultado será zero.

CASESAFEID

Descrição: Converte um ID de 15 caracteres em um ID de 18 caracteres que não diferencia

maiúsculas de minúsculas.
Use: CASESAFEID(id) e substitua id com o ID do objeto.
Exemplo: CASESAFEID (Id)

Essa fórmula substitui o ID de 15 caracteres pelo ID de 18 caracteres e não

diferencia maiúsculas de minúsculas.
Dicas:
◾ Converta para IDs de 18 caracteres para maior compatibilidade com o Excel.
◾ A função CASESAFEID está disponível em qualquer lugar onde se possa
definir uma fórmula, exceto relatórios e s-controls.

CEILING

Descrição: Arredonda um número para o maior número inteiro mais próximo.

Use: CEILING(number) e substitua number pelo campo ou pela expressão que
deseja arredondar.
Exemplo: Arredondamento (valor literal)
CEILING(2.5)

A fórmula retorna 3, que é 2,5 arredondado para o maior número mais próximo.

Magnitude de terremoto
CEILING(Magnitude__c) retorna o valor de um campo de número de
fórmula que calcula a magnitude de um terremoto para o número inteiro mais
próximo.

CONTAINS

Descrição: Compara dois argumentos de texto e retorna TRUE se o primeiro argumento

contiver o segundo argumento. Caso contrário, retornará FALSO.
Use:

http://help.salesforce.com/apex/HTPrint?id=customize_functions_a_h.htm&language... 20/01/2014
 Página 10 de 15

CONTAINS(texto, comparar_texto) e substitua texto, comparar_texto pelo

texto que contiver o valor de comparar_texto.
Exemplo: IF(CONTAINS(Product_Type__c, "part"), "Parts",
"Service")

A fórmula verifica o conteúdo de um campo de texto personalizado denominado

Tipo_de_produto e retorna “Peças” para qualquer produto que contenha a
palavra “peça”. Caso contrário, retorna “Serviço”. Observe que os valores
diferenciam maiúsculas de minúsculas, portanto, se um campo
Tipo_de_produto contiver o texto “Peça” ou “PEÇA, a fórmula retornará
”Serviços“.
Dicas:
◾ Esta função diferencia maiúsculas de minúsculas. Portanto, verifique se o
valor de comparar_texto usa as letras corretas.
◾ Quando essa função é usada em uma regra de validação ou de fluxo de
trabalho, os campos em branco são considerados válidos. Por exemplo, se
você tem uma regra de validação que testa se o número de série de um
patrimônio contém “A”, todos os patrimônios com um número de série em
branco são considerados válidos.
◾ A função CONTAINS não suporta listas de opções de seleção múltipla. Usa
INCLUDES para ver se uma lista de opções de seleção múltipla tem um
valor específico.

DATE

Descrição: Retorna um valor de data dos valores de ano, mês e dia inseridos. O Salesforce
apresenta um erro na página de detalhes quando o valor da função DATE de um
campo de fórmula é uma data inválida, como 29 de fevereiro em um ano que não
seja bissexto.
Use: DATE(year,month,day) e substitua year por um ano de quatro dígitos, month
por um mês de dois dígitos e day por um dia de dois dígitos.
Exemplo: DATE(2005, 01, 02) cria um campo de data para 2 de janeiro de 2005.

DATEVALUE

Descrição: Retorna um valor de data para uma expressão de data/hora ou texto.

Use: DATEVALUE(expression) e substitua expression por um valor de data e hora
ou de texto, um campo de mesclagem ou uma expressão.
Exemplo: Data de fechamento

DATEVALUE(ClosedDate) exibe um campo de data baseado no valor do

campo Data/Hora de fechamento.

Valor de data

DATEVALUE("2005-11-15") retorna 15 de novembro de 2005 como um

valor de data.
Dicas:
◾ Se o campo referenciado na função não for um campo de texto ou data e
hora válido, o campo da fórmula exibirá #ERROR!
◾ Ao inserir uma data, coloque a data entre aspas e use o seguinte formato:
AAAA-MM-DD, ou seja, um ano de quatro dígitos, um mês de dois dígitos e
um dia de dois dígitos.
◾ Se a expressão não corresponder a intervalos de data válidos, como o MM
não estar entre 01 e 12, o campo da fórmula exibirá #ERROR!

http://help.salesforce.com/apex/HTPrint?id=customize_functions_a_h.htm&language... 20/01/2014
 Página 11 de 15

◾ As datas e horas sempre são calculadas com base no fuso horário do

usuário.

DATETIMEVALUE

Descrição: Retorna um ano, mês, dia e um valor de hora GMT.

Use: DATETIMEVALUE(expression) e substitua expression por um valor de data e
hora ou de texto, um campo de mesclagem ou uma expressão.
Exemplo: Data de fechamento

DATETIMEVALUE(ClosedDate) exibe um campo de data baseado no valor

do campo Data/Hora de fechamento.

Valor de data

DATETIMEVALUE("2005-11-15 17:00:00") retorna 15 de novembro de

2005 17h GMT como um valor de data e hora.
Dicas:
◾ DATETIMEVALUE é sempre calculado usando o fuso horário GMT e não
pode ser alterado.
◾ Ao inserir uma data específica, coloque a data entre aspas e use o seguinte
formato: AAAA-MM-DD, ou seja, um ano de quatro dígitos, um mês de dois
dígitos e um dia de dois dígitos.
◾ Se a expressão não corresponder a intervalos de data válidos, como o MM
não estar entre 01 e 12, o campo da fórmula exibirá #ERROR!

DAY

Descrição: Retorna um dia do mês no formato de um número entre 1 e 31.

Use: DAY(date) e substitua date por um campo de data ou um valor como TODAY().
Exemplo: DAY(Code_Freeze__c) retorna o dia da data final de codificação
personalizada. Observe que essa fórmula não funciona em campos de data/hora.

EXP

Descrição: Retorna um valor de e elevado à potência do número especificado.

Use: EXP(number) e substitua number por um campo de número ou um valor como
5.
Exemplo: Expoente de um valor literal

EXP(3)

Esta fórmula retorna o valor de e elevado à terceira potência.

Juros compostos

Principal__c * EXP(Rate__c * Years__c)

Esta fórmula calcula os juros compostos, com base em um campo de moeda

personalizado para o campo de porcentagem personalizado principal para taxa e
para o campo numérico personalizado para anos.

FIND

Descrição: Retorna a posição de uma string em uma string de texto representada como um
número.

http://help.salesforce.com/apex/HTPrint?id=customize_functions_a_h.htm&language... 20/01/2014
 Página 12 de 15

Use: FIND(search_text, text[, start_num]) e substitua search_text pela

string que você deseja encontrar, text pelo campo ou pela expressão a ser
pesquisada e start_num pelo número do caractere a partir do qual começará a
pesquisa da esquerda para a direita.
Exemplo: Rua

FIND(" ", Rua) retorna a posição do caractere do primeiro espaço no campo

Rua. Você pode usar este número para descobrir o comprimento do endereço
residencial como meio de separar um endereço residencial do nome da rua em
um campo de endereço.

Derivando endereços de sites da Web

SUBSTITUTE(Email, LEFT(Email, FIND("@", Email)),

"www.") encontra o local do sinal @ no endereço de email de uma pessoa para
determinar o comprimento do texto a ser substituído por “www.” como meio de
derivar o endereço do site da Web.
Dicas:
◾ Remova os colchetes, [ e ], da fórmula antes de validá-la.
◾ Se o campo citado no parâmetro texto estiver em branco, o campo da
fórmula exibirá 0.
◾ O parâmetro texto_da_pesquisa diferencia maiúsculas de minúsculas e não
pode conter caracteres curinga.
◾ Se a pesquisa não retornar resultados, será exibido um 0 no campo.
◾ O parâmetro núm_inicial é opcional. Se você não inserir um valor para
núm_inicial, a fórmula usará o valor um ou o primeiro caractere da string.
◾ Se núm_inicial não for maior que zero, será exibido um 0 no campo.
◾ Se núm_inicial for maior que o tamanho do texto, será exibido um 0 no
campo.
◾ Ao inserir o parâmetro núm_inicial, lembre-se de que alguns campos, como
Site da Web, são exclusivos, pois um “http://” é automaticamente
anexado ao início do texto inserido.
◾ Observe que o primeiro caractere de uma string é designado como um em
vez de zero.

FLOOR

Descrição: Retorna um número arredondado para o menor número inteiro mais próximo.
Use: FLOOR(number) e substitua number por um campo de número ou um valor
como 5,245.
Exemplo: Valores de comissão

FLOOR(comissão__c) arredonda a comissão para o menor número inteiro

mais próximo

Idade do contato
FLOOR((TODAY()-Birthdate)/365.2425)
Use esta fórmula para calcular a idade da pessoa com base em um campo padrão
denominado Data de nascimento. A Data de nascimento da pessoa
é subtraída da data de hoje, cujo resultado é o número de dias desde a sua Data
de nascimento. Esse número é dividido pelo número de dias em um ano e
arredondado para o menor número inteiro mais próximo.

GETRECORDIDS

Descrição:

http://help.salesforce.com/apex/HTPrint?id=customize_functions_a_h.htm&language... 20/01/2014
 Página 13 de 15

Retorna uma variedade de strings na forma de IDs para os registros selecionados

em uma lista, como um modo de exibição de lista ou uma lista relacionada.
Use: {!GETRECORDIDS(object_type)} e substitua object_type por uma referência
ao objeto personalizado ou padrão dos registros a serem recuperados.
Exemplo de botão {!REQUIRESCRIPT ("/soap/ajax/13.0/connection.js")} var
personalizado: records =
{!GETRECORDIDS($ObjectType.Sample)};
var newRecords = []; if (records[0] == null) { alert
("Please select at least one row") } else {
for (var n=0; n<records.length; n++)
{ var c = new sforce.SObject("Case"); c.id = records
[n]; c.Status = "New";
newRecords.push(c); } result =
sforce.connection.update(newRecords);
window.location.reload(); }

No exemplo, todos os registros de caso selecionados são atualizados com um

Status de “Novo”. Para definir essa configuração em sua organização, crie um
botão de lista personalizado com os seguintes atributos:
◾ O Tipo de exibição é “Botão de lista”
◾ O Comportamento é “Executar JavaScript”
◾ A Origem do conteúdo é “OnClick JavaScript”

Cole o exemplo de código acima no conteúdo do botão personalizado. Por fim,

adicione o botão de lista a um layout de página que contenha a lista relacionada
Casos, como contas ou oportunidades. Os usuários podem selecionar qualquer
número de casos na lista relacionada e clicar no botão de lista para alterar o
status desses casos de uma vez. Observe a marca de records[0] == null,
que exibe uma mensagem aos usuários quando eles não selecionam ao menos
um registro na lista.
Dicas:
◾ Use variáveis globais para acessar campos de mesclagem especiais para s-
controls, botões personalizados e links.
◾ Atividades são tipos especiais de objetos. Use {!GETRECORDIDS
($ObjectType.Task)} ao criar um botão de lista de tarefa. Use {!
GETRECORDIDS($ObjectType.Event)} ao criar um botão de lista de
compromisso.
◾ Essa função só está disponível em botões personalizados, links e s-controls.

GETSESSIONID

Descrição: Retorna o ID da sessão do usuário.

Use: GETSESSIONID()
Exemplo: HYPERLINK
("https://www.myintegration.com?sId="&
GETSESSIONID() & "?&rowID="&Name &
"action=CreateTask","Create
a Meeting Request")
cria um link para um aplicativo fora do Salesforce, passando os parâmetros de
forma que ele possa se conectar ao Salesforce pela API e criar o compromisso
necessário.

HTMLENCODE

Descrição:

http://help.salesforce.com/apex/HTPrint?id=customize_functions_a_h.htm&language... 20/01/2014
 Página 14 de 15

Codifica o texto e os valores do campo de mesclagem para uso no HTML,

substituindo caracteres reservados no HTML, como o sinal “maior que” (>), com
equivalentes da entidade HTML, como &gt;.
Use: {!HTMLENCODE(texto)} e substitua texto pelo campo de mesclagem ou string
de texto que contém os caracteres reservados.
Exemplo: Se o campo de mesclagem foo__c contiver <B>Enter the user's
name<b>, {!HTMLENCODE(foo__c)} resultará em: &lt;B&gt;Enter
the user&#39;s name&lt;/b&gt;
Dicas: Essa função só está disponível em botões personalizados e links.

HYPERLINK

Descrição: Cria um link para um URL especificado que pode ser acessado do texto
especificado.
Use: HYPERLINK(url, friendly_name [,target]) e substitua url pelo endereço
na Web, substitua friendly_name pelo texto do link e, opcionalmente, substitua
target pela janela ou pela estrutura em que o conteúdo será exibido.
Exemplo: Criando compromissos

HYPERLINK("00U/e?
retURL=%2F006x0000001T8Om&what_id="
& Id,
"Create Event")
adiciona um link chamado “Criar evento” que, quando clicado, cria um novo evento
associado ao objeto atual.

Discador de telefone

HYPERLINK("http://servername/call?id=" & Id & "&phone=" & Phone,

Phone) cria um campo de número de telefone com link que disca o número
automaticamente ao ser clicado. Neste exemplo, substitua "nomedoservidor"
e "chamada" pelo nome da sua ferramenta de discagem e pelo comando
utilizado na discagem. O campo de mesclagem, Id, insere o identificador do
contato, lead ou registro da conta. O primeiro campo de mesclagem de
Telefone informa à ferramenta de discagem o número a discar e o último
campo de mesclagem de Telefone utiliza o valor do campo Telefone como o
texto com link que o usuário clica para discar.
Dicas:
◾ Os campos de fórmula de hiperlink são do tipo texto.
◾ Coloque o protocolo e o URL entre aspas, como em HYPERLINK
("http://www.cnet.com", "cnet").
◾ Evite usar funções de texto como LEN, LEFT ou RIGHT nos resultados da
função HYPERLINK.
◾ Ao criar um link para as páginas do Salesforce, use um link relativo, como
"00U/e?retURL=%...", para fórmulas de hiperlink, a menos que deseje
adicionar o campo de fórmula a um layout de pesquisa. Use o URL
completo, incluindo nome do servidor e https://, em uma fórmula de hiperlink
para adicioná-la a um layout de pesquisa. Observe que os campos de
fórmula não estão disponíveis em layouts de resultado de pesquisa.
◾ Use a variável $Api para fazer referência a URLs da API.
◾ Remova os colchetes, [ e ], da fórmula antes de validá-la.
◾ O parâmetro destino é opcional. Se você não especificar um destino, o link
abrirá em uma nova janela do navegador. Estes são alguns parâmetros
destino comuns:
_blank
Exibe um link em uma nova janela sem nome.

http://help.salesforce.com/apex/HTPrint?id=customize_functions_a_h.htm&language... 20/01/2014
 Página 15 de 15

_self
Exibe um link no mesmo quadro ou na mesma janela do elemento a que
se refere.
_parent
Exibe um link no conjunto de quadros imediato, pai do quadro atual. Este
valor será igual a _self se o quadro atual não tiver pai.
_top
Exibe um link em toda a janela original e assim cancela outros quadros.
Este valor será igual a _self se o quadro atual não tiver pai.
Para obter mais informações sobre marcas HTML básicas, consulte uma
referência sobre HTML na Internet.
◾ A função HYPERLINK está disponível em qualquer lugar em que você possa
definir uma fórmula, exceto valores padrão, atualizações de campo, s-
controls, regras de validação, processos de aprovação, botões e links
personalizados, e regras de fluxo de trabalho.

Consulte também:
Operadores e funções de fórmula de I – Z
Operadores de fórmula e funções

Salesforce Success Community

Answers
Help & Training
Collaboration
Ideias
User Groups
Issues
More Places
Salesforce.com
AppExchange
Developer Force
Follow us on Facebook
Follow us on Twitter
Visit our Channel on YouTube
Follow us on Google+
Check us out on LinkedIn
Entre em contato conosco
1-800-NO-SOFTWARE
1-800-667-6389
One Market St.
Suite 300
San Francisco, CA, 94105
United States
Need More Help?
If you still can't find what you're looking for, try to submit a case.

Submit a Case

http://help.salesforce.com/apex/HTPrint?id=customize_functions_a_h.htm&language... 20/01/2014