LÓGICA DE PROGRAMAÇÃO

Lógica
A lógica é o processo de unir pensamentos para atingir
um objetivo mutuo, resolver um problema de forma
inteligente.

É utilizado pelas pessoas que pretendem trabalhar com

desenvolvimento e solução de situações adversas.

Sequências lógicas são passos realizados até atingir a

resolução de um problema.
Lógica de programação
Lógica de programação é a organização coesa de uma
sequência de instruções voltadas à resolução de um
problema, ou à criação de um software ou aplicação.
A lógica de programação é o conhecimento anterior a
qualquer outro quando falamos em desenvolvimento web
porque é a partir dele que os aprendizados posteriores,
como por exemplo o das linguagens de programação, fará
sentido.
Cada linguagem tem suas próprias particularidades, como
sua sintaxe, seus tipos de dados e sua orientação, mas a
lógica por trás de todas é a mesma.
Em outras palavras, dominar a lógica de programação é a
porta de entrada para tornar-se um programador completo,
seja em front-end ou em back-end.
Lógica de programação
Por que aprender lógica de programação é importante?

Organização
Raciocínio lógico
Resolução de problemas
Velocidade de execução
Concentração
Melhor entendimento da tecnologia
 Algoritmo
Algoritmo é uma sequência finita de ações executáveis
que visam obter uma solução para um determinado tipo
de problema.

Também é correto dizer que os "Algoritmos são

procedimentos precisos, não ambíguos, padronizados,
eficientes e corretos".

Embora muitos algoritmos sejam mais

complexos. Eles podem repetir passos ou necessitar de
decisões (tais como comparações ou lógica) até que a
tarefa seja completada.
 Algoritmo
Um algoritmo corretamente executado não irá resolver
um problema se estiver implementado incorretamente
ou se não for apropriado ao problema.

Em suma, algoritmos são sequências de instruções que

realizam uma ou mais tarefas especificas.

O conceito de algoritmo é frequentemente ilustrado

pelo exemplo de uma receita um bolo ou o processo
para ir trabalhar de manhã
 Algoritmo
Exemplo de um algoritmo:
Ir trabalhar pela manhã
1- Acordar
2-Escovar os dentes
3-Tomar banho
4-Vestir-se
5-Tomar café
6-Pegar o transporte
7-Ir ao trabalho
 Programas
Os programas foram criados em uma linguagem de
computador para serem interpretados e executados por
eles.
Programas = Software

Software é um conjunto de instruções que devem ser

seguidas e executadas por um mecanismo, seja ele um
computador ou um aparato eletromecânico.
É o termo genérico usado para descrever programas,
apps, scripts, macros e instruções de código embarcado
diretamente (firmware), de modo a ditar o que uma
máquina deve fazer.
 Programas
Software de sistema - Inclui o firmware (A BIOS dos
computadores pessoais, por exemplo), drivers de
dispositivos, o sistema operacional em si e tipicamente
uma interface gráfica que, em conjunto, permitem ao
usuário interagir com o computador e seus periféricos.

Software aplicativo - Permite ao usuário fazer uma ou

mais tarefas específicas. Aplicativos podem ter uma
abrangência de uso de larga escala, muitas vezes em
âmbito mundial; softwares aplicativos são utilizados para
determinadas tarefas / funções / aplicações
 Fluxograma
Os fluxogramas são utilizados para se referir
graficamente a um algoritmo, processo ou sistema de
computador.
Fluxogramas usam ovais, diamantes, retângulos e
algumas outras formas para determinar os modelos de
passos, além de utilizar setas para conexão das
sequências e fluxo.
Podem ser gráficos simples e desenhados a mão ou por
computador
 Fluxograma
Seta: Um símbolo de conexão usado para ligar dois símbolos e também
informar direção

Terminação: Utilizado para indicar o início/ fim do fluxo

Processo: Utilizado para indicar um processo, funções e atividades

Decisão: Utilizado para mostrar que uma decisão deverá ser tomada
 Fluxograma
Atraso: Utilizado para representar que um tempo será executado antes de
continuar

Dados: Utilizado para significar os tipos de dados no fluxograma

Documento: Utilizado para indicar um tipo de dado / informação que pode ser
lida

Vários documentos: Utilizado para indicar vários documentos

 Fluxograma
Sub-rotina / processo predefinido: Utilizado para indicar processos já definidos

Preparação: Utilizado para mostrar que algo deve ser praticado / ajustado /
modificado no processo

Display: Utilizado para indicar que algo será exibido para leitura na tela.

Entrada manual: Utilizado para mostrar que um procedimento será realizado

de maneira manual
 Fluxograma
Loop manual: Utilizado para indicar que os comandos serão repetidos até que
ocorra uma parada manual

Limite de loop: Utilizado para mostrar o início de uma repetição

Dados armazenados: Mostra que há dados armazenados

Conector: Utilizado para indicar um ponto de inspeção do processo

 Fluxograma
Conector para outra página: Mostra que o processo deve continuar em outro
página

OU: Usando para indicar o "ou" lógico

Somador: Usado para indicar o "e" lógico

Armazenamento interno: Utilizado para indicar armazenamento interno

 Fluxograma
Inicio do
domingo

Acordar

Tomar café

Vou ao cinema Dia de Vou a praia

Sol

Dormir

Fim do dia
 Pseudocódigo

É usado para escrever algoritmos sem que se conheça

alguma linguagem de programação especifica.
Pseudolinguagem é uma linguagem de programação
genérica e rica em detalhes, é usada para escrever
algoritmos de maneira simples e de fácil entendimento.
Já o Portugol é uma pseudolinguagem que possibilita o
programador ficar somente no problema (a solução do
algoritmo) e não no equipamento que irá excetuar o
algoritmo.
 Exemplo do código
Algoritmo "Somando dois números inseridos"
Inicio
Var
x, y, soma: inteiro;
leia (x,y)
soma <- x+y
escreva ("A soma é, soma")
FimAlgoritmo

Estrutura do código
INICIO
<declarações de variáveis>
<comandos>
FIM
 Variáveis
É um item que armazena um tipo de informação.
Essa informação pode se modificar durante a execução
do código / programa / script / processo e etc...
Em portugol utilizaremos os seguintes tipos básicos de
dados:

INTEIRO = somente números inteiros

REAL = para números com casas decimais e negativos
CARACTER = para letras, números e símbolos
LÓGICO = usado para uma resposta lógica
 Variáveis
Ao criar / declarar variáveis cuidados são importantes:
- Não pode existir duas varáveis com o mesmo nome
- Letras escrita em caixa alta e baixa são diferentes
- Não pode começar com um número
- Não pode haver espaços entre as letras
 VisualG
É um software que permite a criação de programas
utilizando a linguagem Portugol;
 VisualG
Novo (Ctrl + N) Localizar (Ctrl + L)
Abrir (Ctrl + A) Localizar próximo (F3)
Salvar (Ctrl + S) Localizar anterior (F4)
Executar (F9) Substituir (Ctrl + L)
Passo a passo (F8) Corrigir indentação (Ctrl + G)
Imprimir (Ctrl + P) Parar (Ctrl + F2)
Cortar (Ctrl + X)
Copiar (Ctrl + C)
Colar (Ctrl + V)
Desfazer (Ctrl + Z)
Refazer (Shift + Ctrl + Z)
 VisualG
Entendendo a estrutura

Algoritmo "nome do algoritmo"

// Função :
// Autor :
// Data :
// Seção de declarações
início
// Seção de Comandos
fimalgoritmo
VisualG - Operadores
Aritméticos
+ Adição
- Subtração
* Multiplicação
/ Divisão
^ Potenciação

Caracteres
+ Concatenação de variáveis
Exemplo: "variavelA" + "variavelB"
VisualG - Operadores
Relacionais
= Igual
< Menor que
> Maior que
<= Menor ou igual
>= Maior ou igual
<> Diferente
VisualG - Operadores
Relacionais
e
O resultado só será verdadeiro se as duas condições
forem verdadeiras

ou
O resultado será verdadeiro se somente uma das
condições for verdadeira

nao
Operador lógico para a negação
Soma exemplo 1
Algoritmo "Soma de dois números"

Var
x, y : inteiro
Inicio
escreva("Digite o primeiro número")
leia(x)
escreva("Digite o segundo número")
leia(y)
escreva("A soma dos dois números é :",x+y)

Fimalgoritmo
Soma exemplo 2
Algoritmo "Soma de dois números"

Var
x, y, resultado : inteiro
Inicio
escreva("Digite o primeiro número")
leia(x)
escreva("Digite o segundo número")
leia(y)
Resultado <- x+y
escreva("A soma dos dois números é :",resultado)

Fimalgoritmo
 EXERCÍCIO

FAÇA UM ALGORITMO QUE RECEBA

DOIS VALORES E AO FINAL DE TUDO
EXIBA AS QUATRO OPERAÇÕES (A
SOMA, SUBTRAÇÃO, MULTIPLICAÇÃO E
A DIVISÃO)
Algoritmo "As quatro operações"

Var
a, b: real

Inicio
escreva("Digite o primeiro número")
leia(a)
escreva("Digite o segundo número")
leia(b)
escreva("A soma é : ",a+b)
escreva("A subtração é : ",a-b)
escreva("A multiplicação é : ",a*b)
escreva("A divisão é : ",a/b)

Fimalgoritmo
 EXERCÍCIO

ESCREVER UM ALGORITMO PARA EXIBIR

O CONSUMO MÉDIO DE UM CARRO
SENDO FORNECIDA A DISTÂNCIA TOTAL
PERCORRIDA PELO AUTOMOVEL E O
TOTAL DO COMBUSTIVEL GASTO
Algoritmo "Consumo médio"

Var
distancia, gasto, total: real

Inicio
escreva("Distancia total percorrida em KM? ")
leia(distancia)

escreva("Quantidade de litros de combustível gastos? ")

leia(gasto)

total <- distancia / gasto

escreva("O consumo médio por quilometro é : ",total)

Fimalgoritmo
 EXERCÍCIO

ESCREVA UM ALGORITMO QUE LEIA 4

NOTAS DE UM ALUNO E EXIBA A MÉDIA
ARITMÉTICA
Algoritmo "Médica aritmética"

Var
a,b,c,d,media: real
Inicio

escreva("Primeira nota")
leia(a)
escreva("Primeira nota")
leia(b)
escreva("Primeira nota")
leia(c)
escreva("Primeira nota")
leia(d)
media <- (a+b+c+d)/4
escreva("A média é : ",media)

Fimalgoritmo
 Condicional
Desvio condicional: É o comando utilizado para desviar a
execução de programa de acordo com uma condição

Desvio simples
Se (condição) então
Lista de comandos
FimSe

Desvio composto
Se (condição) então
Lista de comandos
Senão
Lista de comandos
FimSe
Algoritmo "Exiba o maior número"
Var
a, b : inteiro

Inicio
escreva("Escreva o primeiro número ")
leia(a)
escreva("Escreva o segundo número")
leia(b)

se a > b entao
escreva("A é maior que B")
senao
escreva("B é maior que A")
fimse
Fimalgoritmo
 EXERCÍCIO

ESCREVA UM ALGORITMO QUE LEIA 2

NÚMEROS E DIGA SE SÃO IGUAIS OU
DIFERENTES
Algoritmo "Exiba o maior número"
Var
a, b : inteiro

Inicio
escreva("Escreva o primeiro número ")
leia(a)
escreva("Escreva o segundo número")
leia(b)

se a = b entao
escreva("Os números são iguais")
senao
escreva("Os números são diferentes")
fimse
Fimalgoritmo
 EXERCÍCIO

ESCREVA UM ALGORITMO QUE LEIA 4

NOTAS DE UM ALUNO E EXIBA A MÉDIA
ARITMÉTICA, E EXIBA UMA MENSAGEM
SE O ALUNO FOI APROVADO OU
REPROVADO DE ACORDO COM O A
MÉDIA

MÉDIA 7 PARA SER APROVADO

Algoritmo "Médica aritmética"
Var
a,b,c,d,media: real

Inicio
escreva("Primeira nota")
leia(a)
escreva("Segunda nota")
leia(b)
escreva("Terceira nota")
leia(c)
escreva("Quarta nota")
leia(d)
media <- (a+b+c+d)/4

escreva("A média é : ",media)

se media >=7 entao
escreva(" Aprovado ")
senao
escreva(" Reprovado ")
fimse
fimalgoritmo
Operadores relacionais
Permitem trabalhar com múltiplas condições
relacionais na mesma expressão

Os operadores são: e, ou, nao

Retornam valores lógicos (verdadeiro ou falso)

 Operador e
AND
Somente retorna um valor verdadeiro / real se
todas as condições forem verdadeiras

Condição A Condição B Resultado

Falso Falso Falso
Verdadeiro Falso Falso
Falso Verdadeiro Falso
Verdadeiro Verdadeiro Verdadeiro
Algoritmo "Saber se 3 números são iguais"
Var
a,b,c: inteiro
Inicio

escreva("Primeiro número")
leia(a)
escreva("Segundo número")
leia(b)
escreva("Terceiro número")
leia(c)

se ( (a=b) e (b=c) e (c=a) ) entao

escreva(" Os 3 números são iguais")
senao
escreva(" Pelo menos 1 dos números é diferente ")
fimse
Fimalgoritmo
 EXERCÍCIO

ESCREVA UM ALGORITMO QUE LEIA 4

NOTAS DE UM ALUNO E EXIBA A MÉDIA
ARITMÉTICA, E EXIBA UMA MENSAGEM
SE O ALUNO FOI APROVADO OU
REPROVADO DE ACORDO COM O A
MÉDIA
MÉDIA PARA SER APROVADO 7
SE QUALQUER UMA DAS 4 NOTAS FOR
IGUAL A 0 – O ALUNO ESTÁ REPORVADO
AUTOMATICAMENTE
Algoritmo "Médica aritmética"
Var
a,b,c,d,media: real

Inicio
escreva("Primeira nota")
leia(a)
escreva("Segunda nota")
leia(b)
escreva("Terceira nota")
leia(c)
escreva("Quarta nota")
leia(d)
media <- (a+b+c+d)/4
escreva("A média é : ",media)
se ((media >=7) e (a>0) e (b>0) e (c>0) e (d>0)) entao
escreva(" Aprovado ")
senao
escreva(" Reprovado ")
fimse
fimalgoritmo
 Operador ou
OR
Retorna um valor verdadeiro / real se pelo menos
uma das condições for verdadeiras

Condição A Condição B Resultado

Falso Falso Falso
Verdadeiro Falso Verdadeiro
Falso Verdadeiro Verdadeiro
Verdadeiro Verdadeiro Verdadeiro
Algoritmo "3 números"

Var
a,b,c: inteiro
Inicio
escreva("Primeiro número")
leia(a)
escreva("Segundo número")
leia(b)
escreva("Terceiro número")
leia(c)
se ( (a=b) e (b=c) e (c=a) ) entao
escreva("Todos os lados iguais")
senao
se ( (a=b) ou (b=c) ou (c=a) ) entao
escreva("2 lados iguais")
senao
escreva("Todos os lados diferentes")
fimse
fimse
Fimalgoritmo
 Operador nao
NOT
Retorna um valor verdadeiro / real quando a
condição for falsa
Entrada Saída
Falso Verdadeiro
Verdadeiro Falso

É um operador inverso
Laço de repetição
Esse comando é utilizado para executar uma ação
até que a condição seja verdadeira.
Enquanto a condição for verdadeiro, as
instruções serão executadas.
O laço de repetição é chamado de loop.
Os laços são:
enquanto / faca
repita / ate
para / faca
 enquanto / faca
Esta estrutura de repetição é também chamada
de loop pré-testado, pois a expressão é verificada
antes da primeira execução.
Se inicialmente ela já resultar em FALSO, as
instruções que estão dentro do bloco não são
executadas nenhuma vez.

Enquanto(condição)faca
Lista de comandos
FimEnquanto
enquanto / faca
 enquanto / faca
Vamos implementar um algoritmo para
somar valores até o usuário digitar o
valor 0. Ou seja, vamos somar todos os
valores que o usuário digitar, porém
quando ele digitar 0 o "loop" acaba, a
cada iteração do loop vamos
apresentar o resultado atual da soma.
algoritmo "SomaEnquantoValorDiferenteDe0"
var
valorDigitado : real
soma : real
inicio
soma := 0
escreva ("Digite um valor para a soma: ")
leia (valorDigitado)
enquanto valorDigitado <> 0 faca
soma := soma + valorDigitado
escreva ("Total: ", soma)
escreva ("Digite um valor para a soma: ")
leia(valorDigitado)
fimenquanto
escreva("Resultado: ", soma)
fimalgoritmo
 repita / ate
Outra estrutura de repetição interessante é a REPITA-ATÉ
(Repeat-Until).
A diferença desta estrutura é que ela é um LOOP PÓS-
TESTADO, isto é, o teste para verificar se o bloco será
executado novamente, acontece no final do bloco.
Isso garante que as instruções dentro deste bloco serão
executadas ao menos uma vez. Veja como é o esquema
do REPITA-ATÉ.

Repita
Lista de comandos
Ate(condição)
repita / ate
 repita / ate
Com a estrutura de repetição REPITA-ATÉ
não é necessário escrever duas vezes a
leitura de dados do usuário, pois ela é pós-
testada.
algoritmo "SomaAteValorIgualA0"
var
valorDigitado : real
soma : real
inicio
soma := 0
repita
escreva ("Digite um valor para a soma: ")
leia (valorDigitado)
soma := soma + valorDigitado
escreva ("Total: ", soma)
ate valorDigitado = 0
escreva("Resultado: ", soma)
fimalgoritmo
 para / faca
Podemos implementar esse LOOP com qualquer
estrutura de repetição, mas para isso é necessário
utilizar um contador, uma variável que será utilizada para
contar quantas iterações foram executadas até o
momento.
A estrutura de repetição PARA, implementa um contador
implicitamente.
para / faca
 para / faca
Criamos um algoritmo que será
digitado 15 idades e mostrará a
mensagem informando se é ou não
maior de idade para cada uma das 15
pessoas
algoritmo "paraFaça"

var
x: inteiro
idade: inteiro
inicio
para x de 1 ate 15 faca
escreva("Digite a idade : ")
leia(idade)
se idade >= 18 entao
escreva("Maior de idade")
senao
escreva("De menor!")
fimse
fimpara
fimalgoritmo
 escolha / caso
A estrutura ESCOLHA-CASO, é utilizado
em situações onde existem várias
estruturas Se aninhadas.
A ideia da estrutura Escolha-Caso é
permitir ir direto no bloco de código
desejado, dependendo do valor de uma
variável de verificação
escolha / caso
 escolha / caso
Escreveremos um algoritmo que
solicitará um número.
Logo após, solicitaremos outro número
Em seguida, solicitaremos o operador
matemático.
E por fim, mostraremos o resultado da
operação escolhida.
Algoritmo "Escolha-caso"
Var
num1, num2, resultado: real
op : caractere
Inicio
escreva("Digite o primeiro numero : ")
leia(num1)
escreva("Digite o segundo numero : ")
leia(num2)
escreva("Escolha a operação matmática : ")
leia(op)
escolha op
caso "+"
resultado:=num1+num2
caso "-"
resultado:=num1-num2
caso "x"
resultado:=num1*num2
caso "/"
resultado:=num1/num2
fimescolha
escreva("O resultado é : ",resultado)
Fimalgoritmo
 escolha / caso
Existe uma opção a mais nessa estrutura,
justamente para tratar quando o valor da
variável não é equivalente a nenhum valor
informado como opção nos CASOs, ou seja, é
um "OUTROCASO".

No algoritmo listado anteriormente, imagine

se o usuário digitasse um valor diferente de
"+", "-", "*" e "/".

Caso quiséssemos apresentar uma mensagem

para o usuário informando que ele digitou
uma opção inválida, utilizaríamos esse recurso
da estrutura ESCOLHA-CASO
escolha op
caso "+"
resultado:=num1+num2
caso "-"
resultado:=num1-num2
caso "x"
resultado:=num1*num2
caso "/"
resultado:=num1/num2
outrocaso
escreva("A operação digitada é invalida")

fimescolha
escreva("O resultado é : ",resultado)
Vetores e Matrizes
Vetores e Matrizes são estruturas de dados muito simples que
podem nos ajudar muito quando temos muitas variáveis do
mesmo tipo em um algoritmo.

Imagine o seguinte problema:

Você precisa criar um algoritmo que lê o nome e as 4 notas de
50 alunos, calcular a média de cada aluno e informar quais
foram aprovados e quais foram reprovados.
Conseguiu imaginar quantas variáveis você vai precisar? Muitas
né? Vamos fazer uma conta rápida: 50 variáveis para armazenar
os nomes dos alunos, (4 * 50 = ) 200 variáveis para armazenar
as 4 notas de cada aluno e por fim, 50 variáveis para armazenar
as médias de cada aluno.
300 variáveis no total, sem contar a quantidade de linhas de
código que você vai precisar para ler todos os dados do usuário,
calcular as médias e apresentar os resultados.
Vetores e Matrizes
Vetor (array uni-dimensional) é uma variável
que armazena várias variáveis do mesmo tipo.
No problema apresentado anteriormente, nós
podemos utilizar um vetor de 50 posições para
armazenar os nomes dos 50 alunos.

Matriz (array multi-dimensional) é um vetor de

vetores. No nosso problema, imagine uma
matriz para armazenar as 4 notas de cada um
dos 50 alunos. Ou seja, um vetor de 50
posições, e em cada posição do vetor, há outro
vetor com 4 posições. Isso é uma matriz.
 EXERCÍCIO

CRIE UM ALGORITMO PARA SOMA DOS

ELEMENTOS DO VETOR X[1..10]
Algoritmo "soma em vetor"

var
x : vetor [1..10] de inteiro
contador, soma : inteiro
inicio
soma <- 0
para contador de 1 ate 10 faca
escreva ("Digite um número para somar")
leia(x[contador])
soma <- soma+x[contador]
fimpara
escreva("A soma dos números é : ",soma)
fimalgoritmo
PROBLEMA: Exibir a média aritmética de 5 alunos e mostrar se foram aprovados ou reprovados

Algoritmo "Vetor e matrizes"

var
nomes: vetor [1..5] de caractere
notas: vetor [1..5,1..4] de real
medias: vetor [1..5] de real
contadorA, contadorB: inteiro
inicio
//Leitura dos nomes e as notas de cada aluno
para contadorLoop1 de 1 ate 5 faca
escreva("Digite o nome do aluno(a) número ", contadorA, " de 5: ")
leia(nomes[contadorA)
para contadorB de 1 ate 4 faca
escreva ("Digite a nota ", contadorB, " do aluno(a) ", nomes[contadorA], ": ")
leia(notas[contadorA, contadorB])
fimpara

//CÁLCULO DAS MÉDIAS

medias[contadorA] := (notas[contadorA, 1] + notas[contadorA, 2] + notas[contadorA, 3] + notas[contadorA, 4]) / 4
fimpara
 //APRESENTAÇÃO DOS RESULTADOS
para contadorA de 1 ate 5 faca
se medias[contadorA] >= 7 entao
escreva("O aluno(a) ", nomes[contadorA], " foi aprovado com as notas (", notas[contadorA, 1], ", ", notas[contadorA,
2], ", ", notas[contadorA, 3], ", ", notas[contadorA, 4], ") e média: ", medias[contadorA])
senao
escreva("O aluno(a) ", nomes[contadorA], " foi reprovado com as notas (", notas[contadorA, 1], ", ", notas[contadorA,
2], ", ", notas[contadorA, 3], ", ", notas[contadorA, 4], ") e média: ", medias[contadorA])
fimse
fimpara
fimalgoritmo
 PRATICA E REVISÃO

FAÇA UM ALGORITMO QUE SOLICITE

TRÊS NÚMEROS E NO FINAL MOSTRE O
RESULTADO DAS SUAS SOMAS
 PRATICA E REVISÃO

FAÇA UM ALGORITMO QUE SOLICITE

UM VALOR E NO FINAL EXIBA UMA
MENSAGEM SE ESTE NÚMERO FOR
MAIOR QUE 15
 PRATICA E REVISÃO

A LOJA XINGLING ESTÁ COM UMA

PROMOÇÃO DE VENDA DE PRODUTOS
EM 5 PARCELAS SEM JUROS. FAÇA UM
ALGORITMO QUE RECEBA O VALOR DA
COMPRA E MOSTRE NO FINAL O VALOR
DE CADA PRESTAÇÃO
 PRATICA E REVISÃO

FAÇA UM ALGORITMO QUE RECEBA

DOIS VALORES E MOSTRE SE ELES SÃO
IGUAIS OU SE SÃO DIFERENTES.

CASO SEJAM IGUAIS MOSTRE UMA

MENSAGEM DIZENDO QUE SÃO IGUAIS

CASO SEJAM DIFERENTES MOSTRE O

MAIOR NÚMERO E EXIBA A MENSAGEM
DIZENDO QUE SÃO DIFERENTES
 PRATICA E REVISÃO

FAÇA UM ALGORITMO QUE SOLICITE O

NÚMERO DO MÊS DE 1 ATÉ 12 E
INFORME NA TELA, O MÊS POR ESCRITO

EXEMPLO: SE DIGITAR O NÚMERO 1

TEM QUE APARECER JANEIRO
 PRATICA E REVISÃO

FAÇA UM ALGORITMO PARA O QUAL É

SOLICITADO UM NÚMERO, E NO FINAL,
EXIBA A MENSAGEM SE O NÚMERO
ESTÁ NO INTERVALO DE 100 ATÉ 200
 PRATICA E REVISÃO

FAÇA UM ALGORITMO ONDE É

SOLICITADO QUE SE DIGITE O NOME E
TAMBÉM O SEXO DE CINCO PESSOAS E
NO FINAL DEVERÁ SER EXIBIDO O
NOME DAS PESSOAS E TAMBÉM SE ELA
É HOMEM OU MULHER
E POR FIM EXIBA A QUANTIDADE DE
HOMENS E MULHERES
 PRATICA E REVISÃO

USANDO A ESTRUTURA ENQUANTO /

FACA: ELABORE UM ALGORITMO PARA
SOMAR O NÚMEROS ATÉ QUE SEJA
DIGITADO O VALOR –1.
QUANDO FOR DIGITADO –1 O LOOP
ACABA.
A CADA EXCEUÇÃO DO LOOP DEVE
APRESENTAR O RESULTADO ATUAL DA
SOMA
 PRATICA E REVISÃO

FAÇA UM ALGORITMO QUE SOLICITE 3

NÚMEROS E DIGA SE TODOS SÃO
IGUAIS, DE DOIS DELE SÃO IGUAIS E SE
TODOS SÃO DIFERENTES