!

***** EXEMPLO 5 - Modelo sólido de um pilar (momento aplicado)*****

FINISH
/CLEAR

/VIEW,1,1,1,1 ! DEFINE A DIREÇÃO DE VISUALIZAÇÃO DO DISPLAY

! *** PRÉ-PROCESSAMENTO ***

/PREP7

! *** DEFINIÇÃO DO TIPO DE ELEMENTO ***

ET,1,SOLID45 ! DEFINE O TIPO DE ELEMENTO 1(SÓLIDO 3D)

ET,2,MASS21 ! DEFINE O TIPO DE ELEMENTO 2(MASSA)

! *** DEFINIÇÃO DAS REAIS CONSTANTES ***

R,1 ! REAL CONSTANT 1 SEM NENHUM VALOR ATRIBUÍDO

! *** PROPRIEDADES DO MATERIAL ***

MP,EX,1,205000
MP,PRXY,1,0.3

! *** DEFINIÇÃO DA GEOMETRIA ***

BLOCK,0,200,0,1000,0,200, ! CRIA UM VOLUME DE BLOCO BASEADO NAS COORDENADAS

WPOFFS,,400 ! DESLOCA O PLANO DE TRABALHO

WPROTA,,90 ! ROTACIONA O PLANO DE TRABALHO

VSBW,1,,DELETE ! DIVIDE OS VOLUMES DO PLANO DE TRABALHO

! *** DISCRETIZAÇÃO DO MODELO ***

TYPE,1 ! DISCRETIZAÇÃO DO ELEMENTO SÓLIDO

ESIZE,50
VMESH,ALL

TYPE,2 ! DISCRETIZAÇÃO DO ELEMENTO DE MASSA

REAL,1

NSEL,S,LOC,Y,1000 ! SELECIONA UM NOVO SUBCONJUNTO DE NÓS

NSEL,R,LOC,X,100 ! RESSELECIONA UM SUBCONJUNTO DENTRO SUBCONJUNTO
NSEL,R,LOC,Z,100 ! RESSELECIONA UM SUBCONJUNTO DENTRO SUBCONJUNTO
NLIST ! LISTA OS NÓS SELECIONADOS

! RODAR O APDL FEITO ATÉ AGORA, O NÓ LISTADO FOI O 356

! PODE SER MAIS VANTAJOSO USAR MENU E ENCONTRAR O NÓ MANUALMENTE

NCENTRAL=356 ! ATRIBUI A NUMERAÇÃO DO NÓ CENTRAL À VARIÁVEL NCENTRAL

ALLSEL ! SELECIONA TODO O CONJUNTO DE NÓS DO MODELO

E,NCENTRAL ! DEFINE UM ELEMENTO POR CONECTIVIDADE DE NÓ

NSEL,S,LOC,Y,1000 ! SELECIONA UM NOVO SUBCONJUNTO DE NÓS
CERIG,NCENTRAL,ALL,UXYZ ! CRIA ELEMENTOS RÍGIDOS QUE LIGAM O ELEMENTO

ALLSEL ! SELECIONA TODO O CONJUNTO DE NÓS DO MODELO

FINISH
! *** SOLUÇÃO ***

/SOLU

! *** CARREGAMENTO E CONDIÇÕES DE APOIO ***

DA,3,ALL ! ENGASTE NA ÁREA DE BASE

F,NCENTRAL,MY,20000000 ! MOMENTO TORSOR = 20 kN.m = 20000000 N.mm
SOLVE
FINISH

! *** PÓS-PROCESSAMENTO ***

!/POST1
!PLNSOL,U,X,0,1 ! EXIBE O DESLOCAMENTO EM X
!PLNSOL,ROT,Y,0,1 ! EXIBE OS VALORES DE DESLOCAMENTO DE ROTAÇÃO EM Y

!NSEL,S,LOC,Y,0,400 ! SELECIONA O CONJUNTO DE NÓS COM BASE NA LOCALIZAÇÃO

!ESLN,S ! SELECIONA OS ELEMENTOS ASSOCIADOS AOS NÓS SELECIONADOS
!PLNSOL,S,INT,0,1 ! EXIBE A INTENSIDADE DA TENSÃO NOS ELEMENTOS SELECIONADOS